Failed jobs keep their kind: units that broke or timed out get a failure panel entry with the reason systemd reports (exit status, signal, timeout, start limit, status text) and their last journal lines read through libsystemd. Units that failed only through a dependency are dimmed and left out of the panel, and units that crash after starting count as failed. Restructure the repository around this: - move the library and binary into bootvine/ and the scripted demos into their own unpublished scripted-demos crate, with their VHS tapes - move the crane builds and NixOS module into nix/ - group each sample VM with its check under vm-tests/, adding text-console, scripted-initrd, encrypted-volume and failures machines and a vm-failures check - add docs/guide.md walking through the screen with every recording, keep one recording in the README, and re-render all recordings
50 lines
1.3 KiB
Nix
50 lines
1.3 KiB
Nix
{ machine }:
|
|
{
|
|
name = "bootvine-failures";
|
|
|
|
nodes.machine =
|
|
{ pkgs, ... }:
|
|
let
|
|
holdUntilReleased =
|
|
marker: "${pkgs.bash}/bin/bash -c 'until [ -e /run/${marker} ]; do sleep 0.1; done'";
|
|
in
|
|
{
|
|
imports = [ machine ];
|
|
bootvineSample.startFailuresByHand = true;
|
|
testing.initrdBackdoor = true;
|
|
|
|
boot.initrd.systemd = {
|
|
storePaths = [ "${pkgs.bash}/bin/bash" ];
|
|
services.initrd-failures-hold = {
|
|
description = "Initrd held for the check";
|
|
wantedBy = [ "initrd.target" ];
|
|
before = [ "initrd.target" ];
|
|
unitConfig.DefaultDependencies = false;
|
|
serviceConfig = {
|
|
Type = "oneshot";
|
|
ExecStart = holdUntilReleased "release-initrd-failures-hold";
|
|
};
|
|
};
|
|
};
|
|
|
|
systemd.services.boot-failures-hold = {
|
|
description = "Boot held for the check";
|
|
wantedBy = [ "multi-user.target" ];
|
|
serviceConfig = {
|
|
Type = "oneshot";
|
|
ExecStart = holdUntilReleased "release-boot-failures-hold";
|
|
};
|
|
};
|
|
|
|
virtualisation = {
|
|
memorySize = 2048;
|
|
qemu.options = [
|
|
"-vga none"
|
|
"-device virtio-vga,xres=1280,yres=800"
|
|
];
|
|
};
|
|
};
|
|
|
|
testScript = builtins.readFile ../shared/console.py + builtins.readFile ./check.py;
|
|
}
|