Files
bootvine/vm-tests/hibernate-resume/check.nix
T
Willem Vanhulle 16637c3b38 fix: keep the nixpkgs test import a path so the flake evaluates on upstream Nix
Interpolating pkgs.path into a string asks for a copy in the store, which
nix flake check --no-build never creates, so upstream Nix stopped with a path
that is not valid. That failed the checks on main and skipped the release.
2026-11-02 20:30:44 +01:00

45 lines
1.1 KiB
Nix

{ machine, pkgs, ... }:
{
name = "bootvine-hibernate-resume";
nodes.machine =
{ lib, ... }:
{
imports = [
machine
(pkgs.path + "/nixos/tests/common/auto-format-root-device.nix")
];
boot.resumeDevice = "/dev/vdc";
swapDevices = lib.mkOverride 0 [
{
device = "/dev/vdc";
options = [ "x-systemd.makefs" ];
}
];
powerManagement = {
powerDownCommands = "systemctl --no-block stop backdoor.service";
resumeCommands = "systemctl --no-block restart backdoor.service";
};
virtualisation = {
memorySize = 2048;
qemu.options = [
"-vga none"
"-device VGA,xres=1280,yres=800"
"-chardev socket,id=recording-monitor,path=recording-monitor,server=on,wait=off"
"-mon chardev=recording-monitor,mode=readline"
];
emptyDiskImages = [ 4096 ];
useNixStoreImage = true;
useEFIBoot = true;
};
};
testScript =
builtins.readFile ../shared/console.py
+ builtins.readFile ../shared/screen_recording.py
+ builtins.readFile ./check.py;
}