export RUSTFLAGS := "-C target-cpu=native"
export WEBKIT_DISABLE_COMPOSITING_MODE := "1"

build:
  cargo tauri build --no-bundle -- --profile dev

run:
  cargo tauri dev

fmt:
  cargo +nightly fmt

_fix:
  cargo fix
  cargo clippy --fix

fix: _fix fmt

clippy:
  cargo clippy

test:
  cargo test --workspace

clean:
  cargo clean

peer-cli-build:
  cargo build -p lanspread-peer-cli

peer-cli-image:
  docker build -f crates/lanspread-peer-cli/Dockerfile -t lanspread-peer-cli:dev .

# macvlan: each peer container gets its own MAC/IP on the real LAN.
# Override on the command line if your LAN differs, e.g.
#   just LANSPREAD_PARENT_IFACE=enp4s0 LANSPREAD_SUBNET=10.0.0.0/24 LANSPREAD_GATEWAY=10.0.0.1 peer-cli-net
LANSPREAD_NET := "lanspread"
LANSPREAD_PARENT_IFACE := "eth0"
LANSPREAD_SUBNET := "192.168.1.0/24"
LANSPREAD_GATEWAY := "192.168.1.1"

peer-cli-net:
  docker network inspect {{LANSPREAD_NET}} >/dev/null 2>&1 || \
    docker network create -d macvlan \
      --subnet={{LANSPREAD_SUBNET}} \
      --gateway={{LANSPREAD_GATEWAY}} \
      -o parent={{LANSPREAD_PARENT_IFACE}} \
      {{LANSPREAD_NET}}

peer-cli-run NAME: peer-cli-net
  mkdir -p "target/peer-cli/{{NAME}}/state" "target/peer-cli/{{NAME}}/games"
  docker run --rm --init --network {{LANSPREAD_NET}} --name "lanspread-peer-cli-{{NAME}}" -i \
    -v "$PWD/target/peer-cli/{{NAME}}/state:/state" \
    -v "$PWD/target/peer-cli/{{NAME}}/games:/games" \
    lanspread-peer-cli:dev \
    --name "{{NAME}}" \
    --games-dir /games \
    --state-dir /state \
    --catalog-db /app/game.db