std/vp8: implement loop filters

This commit, part of a series, is inspired by pull request PR #168 by
Damian Kaczmarek (with AI assistance), with some modifications.

Updates PR #168
This commit is contained in:
Nigel Tao committed 2026-06-18 17:22:40 +10:00
1 parent 487922dab4
commit 7b69762670
5 files changed
+1385 -11

No files matched your search

+554
View File
@@ -0,0 +1,554 @@
// Copyright 2026 The Wuffs Authors.
//
// Licensed under the Apache License, Version 2.0 <LICENSE-APACHE or
// https://www.apache.org/licenses/LICENSE-2.0> or the MIT license
// <LICENSE-MIT or https://opensource.org/licenses/MIT>, at your
// option. This file may not be copied, modified, or distributed
// except according to those terms.
//
// SPDX-License-Identifier: Apache-2.0 OR MIT
// --------
// RFC 6386 Section 15.2 Simple Filter.
pri func decoder.filter_simple!(workbuf: slice base.u8, mby: base.u32[..= 0x3FF]) {
var mbx : base.u32
var filter_index : base.u32
var filter_bits : base.u32
var wy : base.u64
mbx = 0
while mbx < this.mbw {
assert mbx < 0x400 via "a < b: a < c; c <= b"(c: this.mbw)
filter_index = this.mb_filters[args.mby & 1][mbx] as base.u32
filter_bits = this.loop_filters[filter_index & 7]
if filter_bits == 0 {
mbx += 1
continue
}
// "decode_one_macroblock's (not skip)" also triggers inner filters.
filter_bits |= (filter_index & 8) << 28
wy = ((((args.mby * this.workbuf_yuv_y_stride) + mbx) * 16) as base.u64) + 0
// Inter-filter horizontally, together with the adjacent macroblock.
if mbx > 0 {
this.filter_2!(
workbuf: args.workbuf,
w: wy + 0x0,
filter_bits: filter_bits ~mod+ 4,
i_step: this.workbuf_yuv_y_stride,
j_step: 1)
}
// Intra-filter (inner) horizontally, within this macroblock.
if filter_bits >= 0x8000_0000 {
this.filter_2!(
workbuf: args.workbuf,
w: wy + 0x4,
filter_bits: filter_bits,
i_step: this.workbuf_yuv_y_stride,
j_step: 1)
this.filter_2!(
workbuf: args.workbuf,
w: wy + 0x8,
filter_bits: filter_bits,
i_step: this.workbuf_yuv_y_stride,
j_step: 1)
this.filter_2!(
workbuf: args.workbuf,
w: wy + 0xC,
filter_bits: filter_bits,
i_step: this.workbuf_yuv_y_stride,
j_step: 1)
}
// Inter-filter vertically, together with the adjacent macroblock.
if args.mby > 0 {
this.filter_2!(
workbuf: args.workbuf,
w: wy,
filter_bits: filter_bits ~mod+ 4,
i_step: 1,
j_step: this.workbuf_yuv_y_stride)
}
// Intra-filter (inner) vertically, within this macroblock.
if filter_bits >= 0x8000_0000 {
this.filter_2!(
workbuf: args.workbuf,
w: wy + ((0x4 * this.workbuf_yuv_y_stride) as base.u64),
filter_bits: filter_bits,
i_step: 1,
j_step: this.workbuf_yuv_y_stride)
this.filter_2!(
workbuf: args.workbuf,
w: wy + ((0x8 * this.workbuf_yuv_y_stride) as base.u64),
filter_bits: filter_bits,
i_step: 1,
j_step: this.workbuf_yuv_y_stride)
this.filter_2!(
workbuf: args.workbuf,
w: wy + ((0xC * this.workbuf_yuv_y_stride) as base.u64),
filter_bits: filter_bits,
i_step: 1,
j_step: this.workbuf_yuv_y_stride)
}
mbx += 1
}
}
// RFC 6386 Section 15.3 Normal Filter.
pri func decoder.filter_normal!(workbuf: slice base.u8, mby: base.u32[..= 0x3FF]) {
var mbx : base.u32
var filter_index : base.u32
var filter_bits : base.u32
var wy : base.u64
var wu : base.u64
var wv : base.u64
mbx = 0
while mbx < this.mbw {
assert mbx < 0x400 via "a < b: a < c; c <= b"(c: this.mbw)
filter_index = this.mb_filters[args.mby & 1][mbx] as base.u32
filter_bits = this.loop_filters[filter_index & 7]
if filter_bits == 0 {
mbx += 1
continue
}
// "decode_one_macroblock's (not skip)" also triggers inner filters.
filter_bits |= (filter_index & 8) << 28
wy = ((((args.mby * this.workbuf_yuv_y_stride) + mbx) * 16) as base.u64) + 0
wu = ((((args.mby * this.workbuf_yuv_uv_stride) + mbx) * 8) as base.u64) + this.workbuf_yuv_y_end
wv = ((((args.mby * this.workbuf_yuv_uv_stride) + mbx) * 8) as base.u64) + this.workbuf_yuv_u_end
// Inter-filter horizontally, together with the adjacent macroblock.
if mbx > 0 {
this.filter_246!(
workbuf: args.workbuf,
w: wy + 0x0,
filter_bits: filter_bits ~mod+ 4,
i_step: this.workbuf_yuv_y_stride,
j_step: 1,
n: 16,
inner: false)
this.filter_246!(
workbuf: args.workbuf,
w: wu + 0x0,
filter_bits: filter_bits ~mod+ 4,
i_step: this.workbuf_yuv_uv_stride,
j_step: 1,
n: 8,
inner: false)
this.filter_246!(
workbuf: args.workbuf,
w: wv + 0x0,
filter_bits: filter_bits ~mod+ 4,
i_step: this.workbuf_yuv_uv_stride,
j_step: 1,
n: 8,
inner: false)
}
// Intra-filter (inner) horizontally, within this macroblock.
if filter_bits >= 0x8000_0000 {
this.filter_246!(
workbuf: args.workbuf,
w: wy + 0x4,
filter_bits: filter_bits,
i_step: this.workbuf_yuv_y_stride,
j_step: 1,
n: 16,
inner: true)
this.filter_246!(
workbuf: args.workbuf,
w: wy + 0x8,
filter_bits: filter_bits,
i_step: this.workbuf_yuv_y_stride,
j_step: 1,
n: 16,
inner: true)
this.filter_246!(
workbuf: args.workbuf,
w: wy + 0xC,
filter_bits: filter_bits,
i_step: this.workbuf_yuv_y_stride,
j_step: 1,
n: 16,
inner: true)
this.filter_246!(
workbuf: args.workbuf,
w: wu + 0x4,
filter_bits: filter_bits,
i_step: this.workbuf_yuv_uv_stride,
j_step: 1,
n: 8,
inner: true)
this.filter_246!(
workbuf: args.workbuf,
w: wv + 0x4,
filter_bits: filter_bits,
i_step: this.workbuf_yuv_uv_stride,
j_step: 1,
n: 8,
inner: true)
}
// Inter-filter vertically, together with the adjacent macroblock.
if args.mby > 0 {
this.filter_246!(
workbuf: args.workbuf,
w: wy,
filter_bits: filter_bits ~mod+ 4,
i_step: 1,
j_step: this.workbuf_yuv_y_stride,
n: 16,
inner: false)
this.filter_246!(
workbuf: args.workbuf,
w: wu,
filter_bits: filter_bits ~mod+ 4,
i_step: 1,
j_step: this.workbuf_yuv_uv_stride,
n: 8,
inner: false)
this.filter_246!(
workbuf: args.workbuf,
w: wv,
filter_bits: filter_bits ~mod+ 4,
i_step: 1,
j_step: this.workbuf_yuv_uv_stride,
n: 8,
inner: false)
}
// Intra-filter (inner) vertically, within this macroblock.
if filter_bits >= 0x8000_0000 {
this.filter_246!(
workbuf: args.workbuf,
w: wy + ((0x4 * this.workbuf_yuv_y_stride) as base.u64),
filter_bits: filter_bits,
i_step: 1,
j_step: this.workbuf_yuv_y_stride,
n: 16,
inner: true)
this.filter_246!(
workbuf: args.workbuf,
w: wy + ((0x8 * this.workbuf_yuv_y_stride) as base.u64),
filter_bits: filter_bits,
i_step: 1,
j_step: this.workbuf_yuv_y_stride,
n: 16,
inner: true)
this.filter_246!(
workbuf: args.workbuf,
w: wy + ((0xC * this.workbuf_yuv_y_stride) as base.u64),
filter_bits: filter_bits,
i_step: 1,
j_step: this.workbuf_yuv_y_stride,
n: 16,
inner: true)
this.filter_246!(
workbuf: args.workbuf,
w: wu + ((0x4 * this.workbuf_yuv_uv_stride) as base.u64),
filter_bits: filter_bits,
i_step: 1,
j_step: this.workbuf_yuv_uv_stride,
n: 8,
inner: true)
this.filter_246!(
workbuf: args.workbuf,
w: wv + ((0x4 * this.workbuf_yuv_uv_stride) as base.u64),
filter_bits: filter_bits,
i_step: 1,
j_step: this.workbuf_yuv_uv_stride,
n: 8,
inner: true)
}
mbx += 1
}
}
pri func decoder.filter_2!(
workbuf: slice base.u8,
w: base.u64,
filter_bits: base.u32,
i_step: base.u32,
j_step: base.u32) {
var n : base.u32
var level : base.u32
var o : base.u64
var p1 : base.u32
var p0 : base.u32
var q0 : base.u32
var q1 : base.u32
var d0 : base.u32
var d1 : base.u32
var a : base.u32
var a1 : base.u32
var a2 : base.u32
level = (args.filter_bits >> 0x00) & 0xFF
n = 16
while n > 0 {
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 2)
if o < args.workbuf.length() {
p1 = args.workbuf[o] as base.u32
}
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
p0 = args.workbuf[o] as base.u32
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 0)
if o < args.workbuf.length() {
q0 = args.workbuf[o] as base.u32
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
q1 = args.workbuf[o] as base.u32
}
while.goto_increment_and_continue true,
inv n > 0,
{{
d0 = this.abs_diff(a: p0, b: q0)
d1 = this.abs_diff(a: p1, b: q1)
if ((d0 ~mod<< 1) ~mod+ (d1 >> 1)) > level {
break.goto_increment_and_continue
}
a = (3 ~mod* (q0 ~mod- p0)) ~mod+ this.clip_m128_p127(a: p1 ~mod- q1)
a1 = this.clip_m16_p15(a: this.util.sign_extend_rshift_u32(a: a ~mod+ 4, n: 3))
a2 = this.clip_m16_p15(a: this.util.sign_extend_rshift_u32(a: a ~mod+ 3, n: 3))
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: p0 ~mod+ a2)
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 0)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: q0 ~mod- a1)
}
break.goto_increment_and_continue
}}.goto_increment_and_continue
args.w ~mod+= args.i_step as base.u64
n -= 1
}
}
pri func decoder.filter_246!(
workbuf: slice base.u8,
w: base.u64,
filter_bits: base.u32,
i_step: base.u32,
j_step: base.u32,
n: base.u32,
inner: base.bool) {
var level : base.u32
var ilevel : base.u32
var hlevel : base.u32
var o : base.u64
var p3 : base.u32
var p2 : base.u32
var p1 : base.u32
var p0 : base.u32
var q0 : base.u32
var q1 : base.u32
var q2 : base.u32
var q3 : base.u32
var d0 : base.u32
var d1 : base.u32
var a : base.u32
var a1 : base.u32
var a2 : base.u32
var a3 : base.u32
level = (args.filter_bits >> 0x00) & 0xFF
ilevel = (args.filter_bits >> 0x08) & 0xFF
hlevel = (args.filter_bits >> 0x10) & 0xFF
while args.n > 0 {
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 4)
if o < args.workbuf.length() {
p3 = args.workbuf[o] as base.u32
}
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 3)
if o < args.workbuf.length() {
p2 = args.workbuf[o] as base.u32
}
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 2)
if o < args.workbuf.length() {
p1 = args.workbuf[o] as base.u32
}
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
p0 = args.workbuf[o] as base.u32
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 0)
if o < args.workbuf.length() {
q0 = args.workbuf[o] as base.u32
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
q1 = args.workbuf[o] as base.u32
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 2)
if o < args.workbuf.length() {
q2 = args.workbuf[o] as base.u32
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 3)
if o < args.workbuf.length() {
q3 = args.workbuf[o] as base.u32
}
while.goto_increment_and_continue true,
inv args.n > 0,
{{
d0 = this.abs_diff(a: p0, b: q0)
d1 = this.abs_diff(a: p1, b: q1)
if ((d0 ~mod<< 1) ~mod+ (d1 >> 1)) > level {
break.goto_increment_and_continue
}
d0 = this.abs_diff(a: p1, b: p0)
d1 = this.abs_diff(a: q0, b: q1)
if (d0 > ilevel) or (d1 > ilevel) or
(this.abs_diff(a: p3, b: p2) > ilevel) or
(this.abs_diff(a: p2, b: p1) > ilevel) or
(this.abs_diff(a: q1, b: q2) > ilevel) or
(this.abs_diff(a: q2, b: q3) > ilevel) {
break.goto_increment_and_continue
}
if (d0 > hlevel) or (d1 > hlevel) {
a = (3 ~mod* (q0 ~mod- p0)) ~mod+ this.clip_m128_p127(a: p1 ~mod- q1)
a1 = this.clip_m16_p15(a: this.util.sign_extend_rshift_u32(a: a ~mod+ 4, n: 3))
a2 = this.clip_m16_p15(a: this.util.sign_extend_rshift_u32(a: a ~mod+ 3, n: 3))
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: p0 ~mod+ a2)
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 0)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: q0 ~mod- a1)
}
} else if args.inner {
a = 3 ~mod* (q0 ~mod- p0)
a1 = this.clip_m16_p15(a: this.util.sign_extend_rshift_u32(a: a ~mod+ 4, n: 3))
a2 = this.clip_m16_p15(a: this.util.sign_extend_rshift_u32(a: a ~mod+ 3, n: 3))
a3 = this.util.sign_extend_rshift_u32(a: a1 ~mod+ 1, n: 1)
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 2)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: p1 ~mod+ a3)
}
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: p0 ~mod+ a2)
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 0)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: q0 ~mod- a1)
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: q1 ~mod- a3)
}
} else {
a = (3 ~mod* (q0 ~mod- p0)) ~mod+ this.clip_m128_p127(a: p1 ~mod- q1)
a = this.clip_m128_p127(a: a)
a1 = this.util.sign_extend_rshift_u32(a: (a ~mod* 0x1B) ~mod+ 63, n: 7)
a2 = this.util.sign_extend_rshift_u32(a: (a ~mod* 0x12) ~mod+ 63, n: 7)
a3 = this.util.sign_extend_rshift_u32(a: (a ~mod* 0x09) ~mod+ 63, n: 7)
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 3)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: p2 ~mod+ a3)
}
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 2)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: p1 ~mod+ a2)
}
o = args.w ~mod- ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: p0 ~mod+ a1)
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 0)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: q0 ~mod- a1)
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 1)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: q1 ~mod- a2)
}
o = args.w ~mod+ ((args.j_step as base.u64) ~mod* 2)
if o < args.workbuf.length() {
args.workbuf[o] = this.clip_255_u8(a: q2 ~mod- a3)
}
}
break.goto_increment_and_continue
}}.goto_increment_and_continue
args.w ~mod+= args.i_step as base.u64
args.n -= 1
}
}
pri func decoder.abs_diff(a: base.u32, b: base.u32) base.u32 {
var c : base.u32
c = args.a ~mod- args.b
if c < 0x8000_0000 {
return c
}
return 0 ~mod- c
}
pri func decoder.clip_m16_p15(a: base.u32) base.u32 {
if (args.a ~mod+ 0x10) <= 0x20 {
return args.a
} else if args.a < 0x8000_0000 {
return 0x0F
}
return 0xFFFF_FFF0
}
pri func decoder.clip_m128_p127(a: base.u32) base.u32 {
if (args.a ~mod+ 0x80) <= 0xFF {
return args.a
} else if args.a < 0x8000_0000 {
return 0x7F
}
return 0xFFFF_FF80
}
pri func decoder.clip_255_u8(a: base.u32) base.u8 {
if args.a <= 255 {
return args.a as base.u8
} else if args.a < 0x8000_0000 {
return 255
}
return 0
}
+81 -1
View File
@@ -61,6 +61,7 @@ pri func decoder.decode_first_partition!(workbuf: roslice base.u8) base.status {
// RFC 6386 Section 9.4. Loop Filter Type and Levels.
this.decode_filter_header!(workbuf: args.workbuf)
this.calculate_loop_filters!()
// RFC 6386 Section 9.5. Token Partition and Partition Data Offsets.
v32 = this.read_unsigned!(workbuf: args.workbuf, part: 0, n: 2)
@@ -204,6 +205,84 @@ pri func decoder.decode_coeff_probs!(workbuf: roslice base.u8) {
}
}
pri func decoder.calculate_loop_filters!() {
var seg : base.u32
var inner : base.u32
var level : base.u32
var ilevel : base.u32
var hlevel : base.u32
seg = 0
while seg < 4 {
inner = 0
while inner < 2,
inv seg < 4,
{
level = this.filt_level as base.u32
if not this.seg_enabled {
// No-op.
} else if not this.filt_deltas_enabled {
level = this.util.sign_extend_convert_u8_u32(a: this.seg_strengths[seg])
} else {
// The (level as base.u32) is redundant, equivalent to level, but
// avoids a -Werror=sign-conversion false positive with gcc 12.2.0.
level = (level as base.u32) ~mod+
this.util.sign_extend_convert_u8_u32(a: this.seg_strengths[seg])
}
// Yes, filt_deltas[*][0], not filt_deltas[*][seg].
if this.filt_deltas_enabled {
level = (level as base.u32) ~mod+
this.util.sign_extend_convert_u8_u32(a: this.filt_deltas[0][0])
if inner <> 0 {
level = (level as base.u32) ~mod+
this.util.sign_extend_convert_u8_u32(a: this.filt_deltas[1][0])
}
}
if level >= 0x8000_0000 {
this.loop_filters[(2 * seg) + inner] = 0
inner += 1
continue
} else if level > 63 {
level = 63
}
ilevel = level
if this.filt_sharpness > 0 {
if this.filt_sharpness <= 4 {
ilevel >>= 1
} else {
ilevel >>= 2
}
ilevel = ilevel.max(no_less_than: (9 - this.filt_sharpness) as base.u32)
}
if (ilevel < 1) or (0x8000_0000 <= ilevel) {
ilevel = 1
}
// If we ever want to support (this.is_key_frame == false), note
// that the hlevel thresholds are a little different then.
if level < 15 {
hlevel = 0
} else if level < 40 {
hlevel = 1
} else {
hlevel = 2
}
level = (2 ~mod* level) ~mod+ ilevel
this.loop_filters[(2 * seg) + inner] =
level | (ilevel ~mod<< 8) | (hlevel ~mod<< 16) | (inner << 31)
inner += 1
}
seg += 1
}
}
pri func decoder.calculate_dequants!() {
var seg : base.u32
var q : base.u32
@@ -218,7 +297,8 @@ pri func decoder.calculate_dequants!() {
} else {
// The (q as base.u32) is redundant, equivalent to q, but avoids a
// -Werror=sign-conversion false positive with gcc 12.2.0.
q = (q as base.u32) ~mod+ this.util.sign_extend_convert_u8_u32(a: this.seg_quants[seg])
q = (q as base.u32) ~mod+
this.util.sign_extend_convert_u8_u32(a: this.seg_quants[seg])
}
this.dequants[seg][0][0] = DEQUANTS[0][this.clip_127(a: q ~mod+ this.quant_ydc_delta)]
+24 -5
View File
@@ -38,8 +38,25 @@ pri func decoder.decode_macroblocks!(workbuf: slice base.u8) base.status {
mbx += 1
}
if (mby <= 0) or (this.filt_level <= 0) {
// No-op.
} else if this.filt_simple {
this.filter_simple!(workbuf: args.workbuf, mby: mby - 1)
} else {
this.filter_normal!(workbuf: args.workbuf, mby: mby - 1)
}
mby += 1
}
if (this.mbh <= 0) or (this.filt_level <= 0) {
// No-op.
} else if this.filt_simple {
this.filter_simple!(workbuf: args.workbuf, mby: this.mbh - 1)
} else {
this.filter_normal!(workbuf: args.workbuf, mby: this.mbh - 1)
}
return ok
}
@@ -47,7 +64,7 @@ pri func decoder.decode_one_macroblock!(workbuf: slice base.u8, mbx: base.u32[..
var v1 : base.u32[..= 1]
var seg : base.u32[..= 3]
var skip : base.bool
var skip : base.u32[..= 1]
var luma_mode : base.u32[..= 4]
var chroma_mode : base.u32[..= 3]
@@ -63,10 +80,9 @@ pri func decoder.decode_one_macroblock!(workbuf: slice base.u8, mbx: base.u32[..
}
}
skip = false
skip = 0
if (this.prob_skip & 0x100) <> 0 {
v1 = this.read_bit!(workbuf: args.workbuf, part: 0, prob: this.prob_skip & 0xFF)
skip = v1 <> 0
skip = this.read_bit!(workbuf: args.workbuf, part: 0, prob: this.prob_skip & 0xFF)
}
luma_mode = this.decode_luma_mode!(workbuf: args.workbuf)
@@ -74,7 +90,7 @@ pri func decoder.decode_one_macroblock!(workbuf: slice base.u8, mbx: base.u32[..
chroma_mode = this.decode_chroma_mode!(workbuf: args.workbuf)
if skip {
if skip <> 0 {
// Clear the HNZC bits.
this.mb_states_left &= 0x0000_FFFF
this.mb_states_top[args.mbx] &= 0x0000_FFFF
@@ -93,6 +109,9 @@ pri func decoder.decode_one_macroblock!(workbuf: slice base.u8, mbx: base.u32[..
this.copy_from_yuv_cache!(
workbuf: args.workbuf, mbx: args.mbx, mby: args.mby)
this.mb_filters[args.mby & 1][args.mbx] =
(((1 ^ skip) << 3) | (seg << 1) | (luma_mode >> 2)) as base.u8
}
// RFC 6386 Section 11.2. Luma Modes.
+37
View File
@@ -88,6 +88,27 @@ pub struct decoder? implements base.image_decoder(
quant_uvdc_delta : base.u32,
quant_uvac_delta : base.u32,
// Look-up tables derived from the loop filter parameters.
//
// The array is indexed by ((2 * segment) + inner), where segment is in
// [0 ..= 3] and inner is in [0 ..= 1]. The inner bit is per any of the
// three equivalent conditions below (C is libwebp, Go is
// golang.org/x/image/vp8, Wuffs is this code):
//
// - what C calls "is_i4x4 == false" / "is_i4x4 == true".
// - what Go calls "usePredY16 == true" / "usePredY16 == false".
// - what Wuffs calls "luma_mode < 4" / "luma_mode >= 4".
//
// The u32 bits are packed like this (unless level == 0, in which case
// the high 24 bits are unused and also all-zero):
//
// - 31 is "is_i4x4", also known as "inner".
// - 24 ..= 30 are unused.
// - 16 ..= 23 are hlevel (high edge variance level).
// - 8 ..= 15 are ilevel (inner level).
// - 0 ..= 7 are level.
loop_filters : array[8] base.u32,
// Look-up tables derived from the dequantization parameters.
//
// The first index is the segment. The second index is Y/Y2/UV. The
@@ -140,6 +161,22 @@ pub struct decoder? implements base.image_decoder(
// The mb_states_top array is indexed by mbx.
mb_states_left : base.u32,
mb_states_top : array[0x400] base.u32,
// Macroblock filter parameters.
//
// The first index is (mby & 1). As we decode rows (and columns) of
// macroblocks, the filter parameters are decoded at the time of the
// R'th row but are applied (to row R) at the time of the (R+1)'th row.
//
// The second index is mbx.
//
// The u8 bits are packed like this:
//
// - 4 ..= 7 are unused
// - 3 is decode_one_macroblock's (not skip).
// - 0 ..= 2 are an index into loop_filters.
//
mb_filters : array[2] array[0x400] base.u8,
)
pub func decoder.get_quirk(key: base.u32) base.u64 {