Add std/png decoder.filter_4_distance_?_arm_neon

On a Raspberry Pi 4 (32-bit armv7l) with -march=native and -mfpu=neon
("native" means "armv8-a+crc+simd"):

wuffs_png_decode_filt_4_dist_3/clang9                      180MB/s ± 0%    217MB/s ± 0%   +20.57%  (p=0.008 n=5+5)
wuffs_png_decode_filt_4_dist_4/clang9                      161MB/s ± 0%    287MB/s ± 0%   +78.75%  (p=0.008 n=5+5)
wuffs_png_decode_image_40k_24bpp/clang9                   99.1MB/s ± 0%   99.4MB/s ± 0%    +0.27%  (p=0.008 n=5+5)
wuffs_png_decode_image_552k_32bpp_ignore_checksum/clang9   123MB/s ± 0%    165MB/s ± 0%   +33.61%  (p=0.008 n=5+5)
wuffs_png_decode_image_552k_32bpp_verify_checksum/clang9   112MB/s ± 0%    146MB/s ± 0%   +29.64%  (p=0.008 n=5+5)
wuffs_png_decode_image_4002k_24bpp/clang9                 93.1MB/s ± 0%   93.2MB/s ± 0%    +0.15%  (p=0.040 n=5+5)

wuffs_png_decode_filt_4_dist_3/gcc8                       80.5MB/s ± 0%  211.7MB/s ± 0%  +163.12%  (p=0.008 n=5+5)
wuffs_png_decode_filt_4_dist_4/gcc8                       77.3MB/s ± 0%  280.4MB/s ± 0%  +262.98%  (p=0.008 n=5+5)
wuffs_png_decode_image_40k_24bpp/gcc8                     98.1MB/s ± 0%  100.8MB/s ± 0%    +2.78%  (p=0.008 n=5+5)
wuffs_png_decode_image_552k_32bpp_ignore_checksum/gcc8     114MB/s ± 0%    162MB/s ± 0%   +41.95%  (p=0.008 n=5+5)
wuffs_png_decode_image_552k_32bpp_verify_checksum/gcc8     103MB/s ± 0%    140MB/s ± 0%   +36.07%  (p=0.008 n=5+5)
wuffs_png_decode_image_4002k_24bpp/gcc8                   93.2MB/s ± 0%   94.1MB/s ± 0%    +0.96%  (p=0.008 n=5+5)
This commit is contained in:
Nigel Tao committed 2021-02-14 23:53:36 +11:00
1 parent 41825fcaae
commit d13039d96e
5 files changed
+428 -3

No files matched your search

+128
View File
@@ -79,3 +79,131 @@ pri func decoder.filter_3_distance_4_arm_neon!(curr: slice base.u8, prev: slice
}
}
}
// --------
// Filter 4: Paeth.
pri func decoder.filter_4_distance_3_arm_neon!(curr: slice base.u8, prev: slice base.u8),
choose cpu_arch >= arm_neon,
{
// See the comments in filter_4_distance_4_arm_neon for an explanation of
// how this works. That function's single loop is copied twice here, once
// with "length: 4" and once with "length: 3". It's generally faster to
// load 4 bytes at a time instead of 3.
//
// Differences between that function and this one are marked with a §.
var c : slice base.u8
var p : slice base.u8
var fa : base.arm_neon_64
var fb : base.arm_neon_64
var fc : base.arm_neon_64
var fx : base.arm_neon_64
var fafb : base.arm_neon_128
var fcfc : base.arm_neon_128
var pa : base.arm_neon_128
var pb : base.arm_neon_128
var pc : base.arm_neon_128
var cmpab : base.arm_neon_128
var cmpac : base.arm_neon_128
var picka : base.arm_neon_64
var pickb : base.arm_neon_64
fa = fa.create_vdup_n_u32(a: 0)
fc = fc.create_vdup_n_u32(a: 0)
// § The advance is 3, not 4.
iterate (c = args.curr, p = args.prev)(length: 4, advance: 3, unroll: 2) {
fb = fb.create_vdup_n_u32(a: p.peek_u32le())
fx = fx.create_vdup_n_u32(a: c.peek_u32le())
fafb = fa.vaddl_u8(b: fb)
fcfc = fc.vaddl_u8(b: fc)
pa = fb.vabdl_u8(b: fc)
pb = fa.vabdl_u8(b: fc)
pc = fafb.vabdq_u16(b: fcfc)
cmpab = pa.vcleq_u16(b: pb)
cmpac = pa.vcleq_u16(b: pc)
picka = cmpab.vandq_u8(b: cmpac).vmovn_u16()
pickb = pb.vcleq_u16(b: pc).vmovn_u16()
fx = fx.vadd_u8(
b: picka.vbsl_u8(b: fa,
c: pickb.vbsl_u8(b: fb, c: fc)))
// § poke_u24le replaces poke_u32le.
c.poke_u24le!(a: fx.vget_lane_u32(b: 0))
fc = fb
fa = fx
} else (length: 3, advance: 3, unroll: 1) {
// § peek_u24le_as_u32 replaces peek_u32le.
fb = fb.create_vdup_n_u32(a: p.peek_u24le_as_u32())
// § peek_u24le_as_u32 replaces peek_u32le.
fx = fx.create_vdup_n_u32(a: c.peek_u24le_as_u32())
fafb = fa.vaddl_u8(b: fb)
fcfc = fc.vaddl_u8(b: fc)
pa = fb.vabdl_u8(b: fc)
pb = fa.vabdl_u8(b: fc)
pc = fafb.vabdq_u16(b: fcfc)
cmpab = pa.vcleq_u16(b: pb)
cmpac = pa.vcleq_u16(b: pc)
picka = cmpab.vandq_u8(b: cmpac).vmovn_u16()
pickb = pb.vcleq_u16(b: pc).vmovn_u16()
fx = fx.vadd_u8(
b: picka.vbsl_u8(b: fa,
c: pickb.vbsl_u8(b: fb, c: fc)))
// § poke_u24le replaces poke_u32le.
c.poke_u24le!(a: fx.vget_lane_u32(b: 0))
// § These assignments are unnecessary; this is the last iteration.
// fc = fb
// fa = fx
}
}
pri func decoder.filter_4_distance_4_arm_neon!(curr: slice base.u8, prev: slice base.u8),
choose cpu_arch >= arm_neon,
{
var c : slice base.u8
var p : slice base.u8
var fa : base.arm_neon_64
var fb : base.arm_neon_64
var fc : base.arm_neon_64
var fx : base.arm_neon_64
var fafb : base.arm_neon_128
var fcfc : base.arm_neon_128
var pa : base.arm_neon_128
var pb : base.arm_neon_128
var pc : base.arm_neon_128
var cmpab : base.arm_neon_128
var cmpac : base.arm_neon_128
var picka : base.arm_neon_64
var pickb : base.arm_neon_64
fa = fa.create_vdup_n_u32(a: 0)
fc = fc.create_vdup_n_u32(a: 0)
iterate (c = args.curr, p = args.prev)(length: 4, advance: 4, unroll: 2) {
fb = fb.create_vdup_n_u32(a: p.peek_u32le())
fx = fx.create_vdup_n_u32(a: c.peek_u32le())
fafb = fa.vaddl_u8(b: fb) // fafb = (fa + fb)
fcfc = fc.vaddl_u8(b: fc) // fcfc = (fc + fc)
pa = fb.vabdl_u8(b: fc) // pa = abs(fa + fb - fc - fa)
pb = fa.vabdl_u8(b: fc) // pb = abs(fa + fb - fc - fb)
pc = fafb.vabdq_u16(b: fcfc) // pc = abs(fa + fb - fc - fc)
cmpab = pa.vcleq_u16(b: pb) // cmpab = (pa <= pb)
cmpac = pa.vcleq_u16(b: pc) // cmpac = (pa <= pc)
picka = cmpab.vandq_u8(b: cmpac).vmovn_u16() // picka = ((pa <= pb) && (pa <= pc))
pickb = pb.vcleq_u16(b: pc).vmovn_u16() // pickb = (pb <= pc)
// Add the predictor to the residual.
fx = fx.vadd_u8(
b: picka.vbsl_u8(b: fa,
c: pickb.vbsl_u8(b: fb, c: fc)))
c.poke_u32le!(a: fx.vget_lane_u32(b: 0))
fc = fb
fa = fx
}
}
+2
View File
@@ -376,6 +376,7 @@ pri func decoder.choose_filter_implementations!() {
choose filter_1 = [filter_1_distance_3_fallback]
choose filter_3 = [filter_3_distance_3_fallback]
choose filter_4 = [
filter_4_distance_3_arm_neon,
filter_4_distance_3_sse42,
filter_4_distance_3_fallback]
} else if this.filter_distance == 4 {
@@ -388,6 +389,7 @@ pri func decoder.choose_filter_implementations!() {
filter_3_distance_4_sse42,
filter_3_distance_4_fallback]
choose filter_4 = [
filter_4_distance_4_arm_neon,
filter_4_distance_4_sse42,
filter_4_distance_4_fallback]
}