Files
bootvine/nix/crane-builds.nix
Willem Vanhulle 8230de065f ci: separate dependency builds, checks and cache uploads
Build the workspace dependencies in their own step, skipped when they are
already in Cachix, so their compile output no longer shares a log with
the build, test and lint results. Steps do not share /nix/store, so later
steps import the paths exported by that step, on pull requests as well.

Push to Cachix in a separate step that alone holds the token and also
runs when a build fails. Pass --quiet to nix in all steps, which removes
the fetch lists and copying lines while keeping builder logs and errors.
2026-11-04 18:17:41 +01:00

88 lines
2.6 KiB
Nix

{
lib,
pkgs,
craneLib,
}:
let
bootvineCrate = craneLib.crateNameFromCargoToml { cargoToml = ../bootvine/Cargo.toml; };
commonArgs = {
inherit (bootvineCrate) pname version;
src = lib.fileset.toSource {
root = ../.;
fileset = lib.fileset.unions [
(craneLib.fileset.commonCargoSources ../.)
../bootvine/system-files
../.rustfmt.toml
];
};
strictDeps = true;
nativeBuildInputs = [ pkgs.pkg-config ];
buildInputs = [
pkgs.dbus
pkgs.systemd
];
};
cargoArtifacts = craneLib.buildDepsOnly (commonArgs // { pname = "bootvine-workspace"; });
buildWorkspaceMember =
args: craneLib.buildPackage (commonArgs // { inherit cargoArtifacts; } // args);
in
{
workspace-dependencies = cargoArtifacts;
rustfmt-formatting = craneLib.cargoFmt {
inherit (commonArgs) src pname version;
cargoExtraArgs = "--all";
};
clippy-lints = craneLib.cargoClippy (
commonArgs
// {
inherit cargoArtifacts;
cargoClippyExtraArgs = "--workspace --all-targets -- --deny warnings";
}
);
bootvine = buildWorkspaceMember {
cargoExtraArgs = "-p bootvine";
postInstall = ''
for unit in bootvine.service bootvine-shutdown.service; do
install -Dm644 bootvine/system-files/systemd/$unit $out/lib/systemd/system/$unit
substituteInPlace $out/lib/systemd/system/$unit \
--replace-fail /usr/bin/bootvine $out/bin/bootvine
done
resume_drop_in=systemd-hibernate-resume.service.d/bootvine.conf
install -Dm644 bootvine/system-files/systemd/$resume_drop_in $out/lib/systemd/system/$resume_drop_in
substituteInPlace $out/lib/systemd/system/$resume_drop_in \
--replace-fail /usr/bin/bootvine $out/bin/bootvine
install -Dm755 bootvine/system-files/dracut/90bootvine/module-setup.sh \
$out/lib/dracut/modules.d/90bootvine/module-setup.sh
install -Dm644 bootvine/system-files/mkinitcpio/install/sd-bootvine \
$out/lib/initcpio/install/sd-bootvine
'';
meta = {
mainProgram = "bootvine";
platforms = lib.platforms.linux;
license = lib.getLicenseFromSpdxId (lib.importTOML ../bootvine/Cargo.toml).package.license;
};
};
scripted-demos = buildWorkspaceMember {
inherit (craneLib.crateNameFromCargoToml { cargoToml = ../scripted-demos/Cargo.toml; })
pname
version
;
cargoExtraArgs = "-p scripted-demos";
doCheck = false;
};
repo-tasks = buildWorkspaceMember {
inherit (craneLib.crateNameFromCargoToml { cargoToml = ../xtask/Cargo.toml; }) pname version;
cargoExtraArgs = "-p xtask";
doCheck = false;
meta.mainProgram = "xtask";
};
}